      SUBROUTINE ZSCAL( N, ZA, ZX, INCX )
*
*     scales a vector by a constant.
*     jack dongarra, 3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER           INCX, N
      COMPLEX*16        ZA
*     ..
*     .. Array Arguments ..
      COMPLEX*16        ZX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER           I, IX, NINCX
*     ..
*     .. Executable Statements ..
*
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         ZX( I ) = ZA*ZX( I )
   10 CONTINUE
      RETURN
*
*        code for increment equal to 1
*
   20 DO 30 I = 1, N
         ZX( I ) = ZA*ZX( I )
   30 CONTINUE
      RETURN
      END
